options nodate nonumber ps=200 ls=80 formdlim=' ';

/* Example 2: Sentencing Data */
   data sentence;
      input type $ prior $ sentence $ count @@;     
      datalines;
   nrb   some  y  42 nrb   some  n 109
   nrb   none  y  17 nrb   none  n  75
   other some  y  33 other some  n 175
   other none  y  53 other none  n 359
   ;
   run;

   proc logistic descending;   /*reverses the order of the response categories*/
      class type prior(ref=first) / param=ref; /*ref=first designates the first ordered level as reference */
      freq count;
      model sentence = type prior / scale=none aggregate; /*scale=none specifies that no correction is needed for the dispersion parameter*/
   run;                          

   ods select GoodnessOfFit;
   proc logistic descending;
      class type prior (ref=first) / param=ref; 
      freq count;
      model sentence = type / scale=none aggregate=(type prior);
   run;

  ods select ClassLevelInfo GoodnessOfFit  
              ParameterEstimates OddsRatios;
   proc logistic data=sentence descending;
      class type prior(ref='none'); 
      freq count;
      model sentence = type prior / scale=none aggregate;
   run;